Прежде чем мы перейдем к следующему разделу, давайте применим все, что мы узнали, для воссоздания макроса property стандартной библиотеки.

Воссоздание макроса property

Обычно макрос property принимает экземпляр TypeDeclaration, который представляет имя, тип и значение по умолчанию, если таковое имеется, переменной экземпляра. Макрос использует это определение для создания переменной экземпляра, а также методов получения и установки для нее.

Макрос property также обрабатывает несколько дополнительных случаев использования, но сейчас давайте сосредоточимся на наиболее распространенном. Наша реализация этого макроса будет выглядеть так:

macro def_getter_setter(decl)

  @{{decl}}

  def {{decl.var}} : {{decl.type}}

    @{{decl.var}}

  end

  def {{decl.var}}=(@{{decl.var}} : {{decl.type}})

  end

end

Мы можем определить переменную экземпляра, используя @{{decl}}, потому что она автоматически расширится до нужного формата. Мы могли бы также использовать @{{decl.var}} : {{decl. type}}, но другой путь был короче и лучше обрабатывал значения по умолчанию. Более длинная форма должна будет явно проверить и установить значение по умолчанию, если таковое имеется, тогда как более короткая форма сделает это за нас. Однако тот факт, что вы можете реконструировать узел вручную, используя предоставляемые им методы, не является совпадением. Узлы AST — это абстрактные представления чего-либо внутри программы, например, объявление типа, метода или выражение оператора if, поэтому имеет смысл только то, что вы можете построить то, что представляет узел, используя сам узел.

Остальная часть нашего макроса def_getter_setter строит методы получения и установки для определенной переменной экземпляра. Отсюда мы можем пойти дальше и использовать его:

class Foo

  def_getter_setter name : String?

  def getter setter number : Int32 = 123

  property float : Float64 = 3.14

end

obj = Foo.new

pp obj.name

obj.name = "Bob"

pp obj.name

pp obj.number

pp obj.float

Запуск этой программы приведет к следующему выводу:

nil

"Bob"

123

3.14

И вот оно! Успешная повторная реализация наиболее распространенной формы макроса property! Здесь легко увидеть, как можно использовать макросы, чтобы уменьшить количество шаблонов и повторений в вашем приложении.

Последняя концепция макросов, которую мы собираемся обсудить в этой главе, — это макро-хуки, которые позволяют нам подключаться к различным событиям Crystal.

Изучение макро-хуков

Перехватчики макросов — это специальные определения макросов, которые в некоторых ситуациях вызываются компилятором Crystal во время компиляции. К ним относятся следующие:

• inherited вызывается, когда определен подкласс, где @type — это наследующий тип.

• included вызывается при включении модуля, где @type — включаемый тип.

• extended вызывается при расширении модуля, где @type — расширяемый тип.

• method_missing вызывается, когда метод не найден, и ему передается один аргумент Call.

• method_added вызывается, когда новый метод определен в текущей области и ему передается один аргумент Def.

• finished вызывается после этапа семантического анализа, поэтому известны все типы и их методы.

Первые три и законченные определения являются наиболее распространенными/полезными, поэтому мы сосредоточимся на них. Первые три хука работают по сути одинаково — они просто выполняются в разных контекстах. Например, следующая программа демонстрирует, как они работают, определяя различные перехватчики и печатая уникальное сообщение при выполнении этого перехватчика:

abstract class Parent

  macro inherited

    puts "#{{{@type.name}}} inherited Parent"

  end

end

module MyModule

  macro included

    puts "#{{{@type.name}}} included MyModule"

  end

  macro extended

    puts "#{{{@type.name}}} extended MyModule"

  end

end

class Child < Parent

  include MyModule

  extend MyModule

end

Предыдущий код выведет следующий результат:

Child inherited Parent

Child included MyModule

Child extended MyModule

Эти перехватчики могут быть весьма полезны, если вы хотите добавить методы/переменные/константы к другому типу в случаях, когда обычная семантика наследования/модуля не работает. Примером этого может служить случай, когда вы хотите добавить к типу методы экземпляра и класса при включении модуля. Из-за того, как работает включение/расширение модулей, в настоящее время невозможно добавить оба типа методов к типу из одного модуля.

Обходной путь — вложить еще один модуль ClassMethods в основной. Однако для этого пользователю потребуется вручную включить основной модуль и расширить вложенный модуль, что не очень удобно для пользователя. Лучшим вариантом было бы определить в основном модуле макрос, включающий ловушку, которая расширяет модуль ClassMethods. Таким образом, макрос будет расширяться внутри включенного класса, автоматически расширяя модуль методов класса. Это будет выглядеть примерно так:

module MyModule

  module ClassMethods

    def foo

      "foo"

    end

  end

  macro included

    extend MyModule::ClassMethods

  end

  def bar

    "bar"

  end

end

class Foo

  include MyModule

end

pp Foo.foo

pp Foo.new.bar

Таким образом, пользователю нужно только включить модуль, чтобы получить оба типа методов, что в целом улучшит взаимодействие с пользователем.

macro finished в основном используется, когда вы хотите выполнить какой-либо макрокод только после того, как Crystal узнает обо всех типах. В некоторых случаях отсутствие вашего макрокода в обработчике finished может привести к неверным результатам. Следите за обновлениями! Мы рассмотрим это более подробно в Главе 15 "Документирование кода".

Резюме

Метапрограммирование — одна из областей, в которой Кристалл преуспевает. Он предоставляет нам довольно мощную систему, которую можно использовать для генерации кода и уменьшения количества шаблонов/повторений, при этом оставаясь при этом достаточно простой по сравнению с другими языками. Однако, когда это необходимо, эту силу следует использовать экономно.

В этой главе мы узнали, как и когда использовать макросы для сокращения шаблонного кода, как подключаться к различным событиям Crystal с помощью перехватчиков макросов, а также познакомились с API макросов для поддержки создания более сложных макросов.

В следующей главе мы рассмотрим аннотации и то, как их можно использовать в сочетании с макросами для хранения данных, которые можно прочитать во время компиляции.

11. Знакомство с аннотациями

Как упоминалось в предыдущей главе, макросы могут быть мощным инструментом для генерации кода, позволяющим уменьшить дублирование и сохранить ваше приложение DRY. Однако одно из ограничений макросов, особенно тех, которые находятся за пределами определения макроса, заключается в том, что сложно получить доступ к данным для использования